Fitxer:Hyperbolic orbit.gif
El contingut de la pàgina no s'admet en altres llengües.
De la Viquipèdia, l'enciclopèdia lliure
Hyperbolic_orbit.gif (300 × 300 píxels, mida del fitxer: 12 Ko, tipus MIME: image/gif, en bucle, 90 fotogrames, 4,2 s)
Aquest fitxer i la informació mostrada a continuació provenen del dipòsit multimèdia lliure Wikimedia Commons. Vegeu la pàgina original a Commons |
a | Semimajor axis |
---|---|
rp | Periapsis' Radius |
υ∞ | Divergence angle |
Resum
DescripcióHyperbolic orbit.gif | Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue). |
Data | |
Font | Own work. Rendered with PovRay-3.0, animated with gifsicle. |
Autor | Brandir |
Permís (Com reutilitzar aquest fitxer) |
Brandir put it under the GFCL and the CC-BY-SA |
Llicència
Jo, el titular dels drets d'autor d'aquest treball, el public sota les següents llicències:
S'autoritza la còpia, la distribució i la modificació d'aquest document sota els termes de la llicència de documentació lliure GNU versió 1.2 o qualsevol altra versió posterior que publiqui la Free Software Foundation; sense seccions invariants, ni textos de portada, ni textos de contraportada. S'inclou una còpia d'aquesta llicència en la secció titulada GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
Aquest fitxer està subjecte a la llicència de Creative Commons Reconeixement i Compartir Igual 3.0 No adaptada. | ||
| ||
Aquest avís de llicència s'ha afegit a aquest fitxer d'acord amb l'actualització de la llicència GFDL.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue |
Aquest fitxer està publicat sota la llicència de Creative Commons Reconeixement i Compartir Igual 2.5 Espanya.
- Sou lliure de:
- compartir – copiar, distribuir i comunicar públicament l'obra
- adaptar – fer-ne obres derivades
- Amb les condicions següents:
- reconeixement – Heu de donar la informació adequada sobre l'autor, proporcionar un enllaç a la llicència i indicar si s'han realitzat canvis. Podeu fer-ho amb qualsevol mitjà raonable, però de cap manera no suggereixi que l'autor us dóna suport o aprova l'ús que en feu.
- compartir igual – Si modifiqueu, transformeu, o generareu amb el material, haureu de distribuir les vostres contribucions sota una llicència similar o una de compatible com l'original
Podeu seleccionar la llicència que vulgueu.
POV-Ray Scene description
POV-ray image description:
/*
--------------------------
Hyperbolic Orbit Animation
--------------------------
Created 7 Mar. 2006
*/
#include "colors.inc"
//Orbit Definition
#declare OrbitA=30;
#declare OrbitE=1.38;
//Scene Constants
#declare EarthRadius=6.356;
#declare SatRadius=1.2;
#declare OrbitWidth=0.5;
#declare LineWidth=0.5/3;
#declare Crosslength=1.5;
#declare Textscale=9;
#declare TextColor=rgb<0,0,0>;
#declare xinit=-35;
//Variables
#declare Minit=OrbitE*sinh(acosh(-(xinit/OrbitA-OrbitE)))-acosh(-(xinit/OrbitA-OrbitE));
#declare M=Minit-2*clock*Minit;
#declare PI=3.14159265359;
#declare Angleinf=180-acos(-1/OrbitE)*(180/PI);
//Anomaly Determination - Solves the equation M=e*sinh(H)-H by the iterative method
#declare Index=0;
#declare prevAnomaly=0;
#declare Anomaly=0;
#while (Index<30)
#declare Anomaly=asinh((M+prevAnomaly)/OrbitE);
#declare prevAnomaly=Anomaly;
#declare Index=Index+1;
#end
//General settings
global_settings{
ambient_light 1
}
light_source { <-50, 0, -70> color White }
camera {
orthographic
location <-10, 0, -10>
look_at <-10, 0, 0>
up <0,100,0>
right <100,0,0>
}
plane { <0, 0, 1>, 8
pigment {White}
finish{ambient 1 brilliance 0}
}
//Earth
sphere {
<0, 0, 0>, EarthRadius
pigment { Blue }
finish{ ambient 0.3 brilliance 1.2 diffuse 0.8}
}
//Orbit
intersection{
box{
<-100,-100,-OrbitWidth>, <100,100,OrbitWidth>
}
quadric{
<1/(OrbitA*OrbitA),-1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<2*OrbitE/OrbitA,0,0>,OrbitE*OrbitE-1
translate x*OrbitWidth/2
}
quadric{
<-1/(OrbitA*OrbitA),1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<-2*OrbitE/OrbitA,0,0>,1-OrbitE*OrbitE
translate -x*OrbitWidth/2
}
pigment{ rgb<0.8,0,0> }
finish{ ambient 1 brilliance 0 diffuse 0}
rotate 2.2*y
no_shadow
}
//Satellite
sphere {
<0, 0, -10>, SatRadius
pigment { SeaGreen }
finish{ ambient 1 brilliance 0 diffuse 0}
no_shadow
translate <-OrbitA*(OrbitE-cosh(Anomaly)),OrbitA*sqrt(OrbitE*OrbitE-1)*sinh(Anomaly),0>
}
//Lines
#declare crossBars=
object{
union{
box{
<-LineWidth,-Crosslength,-LineWidth-7>, <LineWidth,Crosslength,LineWidth-7>
}
box{
<-Crosslength,-LineWidth,-LineWidth-7>, <Crosslength,LineWidth,LineWidth-7>
}
rotate z*45
pigment{ TextColor }
finish{ ambient 1 brilliance 0 diffuse 0}
no_shadow
}
}
box{
<-OrbitA*OrbitE-3,-LineWidth,-LineWidth-7>, <0,LineWidth,LineWidth-7>
pigment{ TextColor }
finish{ ambient 1 brilliance 0 diffuse 0}
no_shadow
}
box{
<0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7>
pigment{ TextColor }
finish{ ambient 1 brilliance 0 diffuse 0}
rotate z*Angleinf
translate -x*OrbitA*OrbitE
no_shadow
}
box{
<0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7>
pigment{ TextColor }
finish{ ambient 1 brilliance 0 diffuse 0}
rotate -z*Angleinf
translate -x*OrbitA*OrbitE
no_shadow
}
difference{
torus{
4,LineWidth
rotate x*90
}
box {
<-5,0,-5>,<5,5,5>
}
box {
<-5,-5,-5>,<5,0,5>
rotate -z*Angleinf
}
pigment{ TextColor }
finish{ ambient 1 brilliance 0 diffuse 0}
translate -z*7
translate -x*OrbitA*OrbitE
no_shadow
}
object{
crossBars
}
object{
crossBars
translate -x*OrbitA*(OrbitE-1)
}
object{
crossBars
translate -x*OrbitA*OrbitE
}
//Text
text {
ttf "timesi.ttf" "a" 1, 0
pigment{ TextColor }
finish{ ambient 1 brilliance 0 diffuse 0}
scale Textscale
translate <OrbitA*(0.5-OrbitE)-Textscale/4,Textscale/4,-7>
no_shadow
}
union{
text {
ttf "timesi.ttf" "r" 1, 0
}
text {
ttf "timesi.ttf" "p" 1, 0
scale 0.5
translate 0.2*x
}
pigment{ TextColor }
finish{ ambient 1 brilliance 0 diffuse 0}
scale Textscale
translate <-(EarthRadius+0.3*(OrbitA*(OrbitE-1)-EarthRadius))-Textscale/4,Textscale/4,-7>
no_shadow
}
union{
text {
ttf "symbol.ttf" "u" 1, 0
matrix
< 1, 0, 0,
0.3, 1, 0,
0, 0, 1,
0, 0, 0 >
}
text {
ttf "symbol.ttf" chr(165) 1, 0
scale 0.5
translate <0.6,-0.1,0>
}
pigment{ TextColor }
finish{ ambient 1 brilliance 0 diffuse 0}
scale Textscale
translate <-OrbitA*OrbitE-Textscale/4+9,-0.6*Textscale,-7>
no_shadow
}
Elements representats en aquest fitxer
representa l'entitat
7 març 2006
image/gif
Historial del fitxer
Cliqueu una data/hora per veure el fitxer tal com era aleshores.
Data/hora | Miniatura | Dimensions | Usuari/a | Comentari | |
---|---|---|---|---|---|
actual | 02:01, 8 març 2006 | 300 × 300 (12 Ko) | Brandir~commonswiki | {{Information| |Description = Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue). |Source = Own work. Rendered with ''PovRay-3.0'', animated with ''gifsicle''. |Date = Created 7. Mar. 2006. |
Ús del fitxer
La pàgina següent utilitza aquest fitxer:
Ús global del fitxer
Utilització d'aquest fitxer en altres wikis:
- Utilització a de.wikiversity.org
- Kurs:Algebraische Kurven (Osnabrück 2008)/Vorlesung 7
- Kurs:Algebraische Kurven (Osnabrück 2012)/Vorlesung 7
- Quadriken/Planetenbewegung/Kepler/Bemerkung
- Kurs:Algebraische Kurven (Osnabrück 2012)/Vorlesung 7/kontrolle
- Kurs:Algebraische Kurven (Osnabrück 2017-2018)/Vorlesung 7
- Kurs:Algebraische Kurven (Osnabrück 2017-2018)/Vorlesung 7/kontrolle
- Utilització a en.wikibooks.org
- Utilització a fr.wikibooks.org
- Utilització a oc.wikipedia.org